Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちら をご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


9 / 13327 ツリー ←次へ | 前へ→

【80933】2回に1回エラーが出る さと 19/6/23(日) 19:23 質問[未読]

【80963】Re:2回に1回エラーが出る さと 19/6/26(水) 12:32 発言[未読]
【80971】Re:2回に1回エラーが出る よろずや 19/6/27(木) 14:22 発言[未読]
【80972】Re:2回に1回エラーが出る よろずや 19/6/27(木) 16:54 発言[未読]
【80977】Re:2回に1回エラーが出る γ 19/6/27(木) 22:10 回答[未読]
【80985】Re:2回に1回エラーが出る さと 19/7/1(月) 12:36 お礼[未読]

【80963】Re:2回に1回エラーが出る
発言  さと  - 19/6/26(水) 12:32 -

引用なし
パスワード
   ▼γ さん:
これが現在のコードで、このように変数の宣言の位置を変えたら、何回も連続で処理を行ってもエラーが全く出なくなりました。

Option Explicit

Sub 当月入力準備()
  Application.ScreenUpdating = False
  With Sheets("7月")
   
   .Range("B2").CurrentRegion.Offset(2, 1).Select

  Dim a As Long, b As Long
  a = Selection.Rows.Count
  b = Selection.Columns.Count

    Selection.Resize(a - 3, b - 1).Select
    Selection.Copy
    .Range("B2").CurrentRegion.Offset(3, 1).Select
    Selection.Resize(a - 3, b - 1).Select
    Selection.PasteSpecial xlPasteValues
    .Range("B2").CurrentRegion.Offset(2, 1).Select
    Selection.Resize(a - 6, b - 1).Select
    Selection.ClearContents
  End With
End Sub

【80971】Re:2回に1回エラーが出る
発言  よろずや  - 19/6/27(木) 14:22 -

引用なし
パスワード
   提示されたものの無駄を省くと、以下の様になります。

Option Explicit
Sub 当月入力準備()
  Dim a As Long, b As Long
  Application.ScreenUpdating = False
  With Sheets("7月").Range("B2")   
    With .CurrentRegion
      a = .Rows.Count
      b = .Columns.Count
    End With
    .Offset(2, 1).Resize(a - 3, b - 1).Copy
    .Offset(3, 1).Resize(a - 3, b - 1).PasteSpecial xlPasteValues
    .Offset(2, 1).Resize(a - 6, b - 1).ClearContents
  End With
End Sub

マクロの記録では、Select Selection がやたら出てきますが、
これらは、基本的には不要です。

処理としてこれで正しいのかどうかは、シートの構成が判りませんので、不明です。

【80972】Re:2回に1回エラーが出る
発言  よろずや  - 19/6/27(木) 16:54 -

引用なし
パスワード
   ▼さと さん:

>  a = Selection.Rows.Count

この文の意味を誤解してるのではないでしょうか?

誤:a と Selection.Rows.Count は同じと定義する。

正:この時点の Selection.Rows.Count の値を a に代入する。

【80977】Re:2回に1回エラーが出る
回答  γ  - 19/6/27(木) 22:10 -

引用なし
パスワード
   既にコメントをいただいていて、重複になって恐縮です。

質問者さん、コードの提示ご苦労さまでした。

変数宣言の位置というよりも
> a = Selection.Rows.Count
> b = Selection.Columns.Count
という命令よりも前に、
.Range("B2").CurrentRegion.Offset(2, 1).Select
を実行していることが重要です。
「コードのなかで選択(Selectionを限定)」していることがポイントです。

つまり、
> ■19/6/23(日) 19:23のコードでは、
> 無造作に
>  a = Selection.Rows.Count
>  b = Selection.Columns.Count
> で始まっている。
> そのとき何が選択されているか分かったものじゃない。
という状態から脱したことが大きいのです。
プロシージャの開始時点における冗長性(可能性が多いこと)がなくなったことが大きいのです。

----------
なお、変数宣言の位置について補足すれば、
実行前であれば、
・使用の直前であっても
・プロシージャーの先頭に纏めても
動作に影響はありません。誤解無きよう。

【80985】Re:2回に1回エラーが出る
お礼  さと  - 19/7/1(月) 12:36 -

引用なし
パスワード
   よろずやさん、γさん

ありがとうございました。
原因が分かってすっきりしました。

9 / 13327 ツリー ←次へ | 前へ→
ページ:  ┃  記事番号:
2610219
(SS)C-BOARD v3.8 is Free